When using a CALL DEFINE with PROC REPORT to apply a URL to a GROUP or ORDER variable, the URL link is applied to every row in the column in SAS® 9.2. In SAS® 9.1, the URL only applied to the GROUP or ORDER variable value. This applies only to ODS destinations.

To apply the link only to the GROUP or ORDER variable value, do one of the following:

• Add the SPANROWS option to the PROC REPORT statement.

• Use a subsetting IF statement to determine if the cell for the row contains a value and then apply the link with a CALL DEFINE and the URL attribute.

Please see the code in the Full Code tab for an example.

Operating System and Release Information

In SAS 9.1, a link is created to the cell with a value within the column. In SAS 9.2, a link is created for every cell in the column.

ods html;

proc report data=sashelp.class nowd split='*';
   columns sex name age;
   define sex /group;
   define name /display;
   define age /display;
   compute sex /char length=55;
      href=sex||'.html';
      call define(_col_,"URL",href);
   endcomp;
run;

ods html close;

/*** SPANROWS workaround ***/ 

/* Modify the C:\ path to a directory that you have write access to. */                                                      
ods pdf file='c:\myfile.pdf' ;

proc report data=sashelp.class nowd split='*' spanrows;
   columns sex name age;
   define sex /group;
   define name /display;
   define age /display;
   compute sex /char length=55;
      href=sex||'.pdf';
      call define(_col_,"URL",href);
   endcomp;
run;

ods pdf close;

/*** Subsetting IF statement workaround ***/ 

ods html;

proc report data=sashelp.class nowd split='*';
   columns sex name age;
   define sex /group;
   define name /display;
   define age /display;
   compute sex;
      if sex ne ' ' then do;
         href=sex||'.html';
         call define(_col_,"URL",href);
      end;
   endcomp;
run;

ods html close;